Enum List DropDown Control

I've been wanting to try this concept out for awhile, and I finally had a reasonable opportunity. The idea was to slap a System.ComponentModel.Description attribute onto each field of an Enum, and then bind a dropdown list directly to the Enum.

I got it working and the code is pretty concise. Please excuse the fact that I'm working in VB for this one; it's my DotNetNuke project, and I was already working in VB to edit some modules. The code would be even prettier in C# I imagine.

First, let's decorate an enum. Import System.ComponentModel here.

        1: Public Enum RegionCode

       2:     <Description("-- Select --")> NotSelected = 0

       3:     <Description("US - Midwest")> Midwest = 1

       4:     <Description("US - Northeast")> Northeast = 2

       5:     <Description("US - Southeast")> Southeast = 3

       6:     <Description("US - Southwest")> Southwest = 4

       7:     <Description("US - West")> West = 5

       8:     Canada = 6

       9: End Enum

Next, we need to build a helper routine that can get the description off of a decorated enum field. It must gracefully handle the case when a description is not specified, as with Canada.

In .NET 3.5, you'd probably want to build these as extension methods, which would be a trivial change. Import System.ComponentModel here too.

       1: ''' <summary>

       2: ''' Get the Description of an enum value

       3: ''' </summary>

       4: ''' <param name="value"></param>

       5: ''' <returns></returns>

       6: ''' <remarks>If there is no description attribute, the name will be used.</remarks>

       7: Public Function GetDescription(ByVal value As System.Enum) As String

       8:     Return GetDescription(value.GetType().GetField(value.ToString))

       9: End Function

      10:  

      11: ''' <summary>

      12: ''' Get the description of a field

      13: ''' </summary>

      14: ''' <param name="field"></param>

      15: ''' <returns></returns>

      16: ''' <remarks>If the field doesn't have a description attribute, the name is used</remarks>

      17: Public Function GetDescription(ByVal field As System.Reflection.FieldInfo)

      18:     ' Get the array of description attributes applied (there will be 0 or 1)

      19:     Dim descriptions() As Object

      20:     descriptions = field.GetCustomAttributes(GetType(DescriptionAttribute), False)

      21:  

      22:     ' If there was a description, return it

      23:     If descriptions.Length > 0 Then

      24:         Return DirectCast(descriptions(0), DescriptionAttribute).Description

      25:     End If

      26:  

      27:     ' Otherwise return the field's name

      28:     Return field.Name

      29: End Function

Now that we can easily grab the description from an enum field, let's build ourselves a new dropdown control.

       1: Imports System.Reflection

       2:  

       3: ''' <summary>

       4: ''' A custom dropdown that binds to an enum

       5: ''' </summary>

       6: ''' <remarks>

       7: ''' The DataSource is set to an Enum type name, not a collection,

       8: ''' and it can be set within the markup if desired

       9: ''' <example><![CDATA[

'''     <app:EnumList Runat="server" ID="ddlRegion" DataSource="MyApp.RegionCode" />

'''     ...

'''     ddlRegion.DataBind()

'''     ddlRegion.SelectedValue = RegionCode.West

''' ]]></example>

''' </remarks>

Public Class EnumList

    Inherits System.Web.UI.WebControls.DropDownList

  

    Private _enumType As Type

    ''' <summary>

    ''' Specify the enum type that we'll bind to

    ''' </summary>

    ''' <value></value>

    ''' <returns></returns>

    ''' <remarks></remarks>

    Public Shadows Property DataSource() As String

        Get

            Return _enumType.ToString

        End Get

        Set(ByVal value As String)

            _enumType = System.Type.GetType(value, True, True)

        End Set

    End Property

  

    ''' <summary>

    ''' Replace SelectedValue with an Enum-based version

    ''' </summary>

    ''' <value></value>

    ''' <returns></returns>

    ''' <remarks></remarks>

    Public Shadows Property SelectedValue() As System.Enum

        Get

            ' Get the value from the request to allow for disabled viewstate

            Dim RequestValue As String = Me.Page.Request.Params(Me.UniqueID)

  

            Return System.Enum.Parse(_enumType, RequestValue)

        End Get

        Set(ByVal value As System.Enum)

            MyBase.SelectedValue = value.ToString

        End Set

    End Property

  

    ''' <summary>

    ''' Replace DataBind so that we can bind to the list of fields in the

    ''' enum.  Call our GetDescription function for each one to get the

    ''' text to display.

    ''' </summary>

    ''' <remarks></remarks>

    Public Overrides Sub DataBind()

        Me.Items.Clear()

        Dim flags As BindingFlags = BindingFlags.Public Or BindingFlags.Static

  

        For Each field As FieldInfo In _enumType.GetFields(flags)

            Me.Items.Add(New ListItem(GetDescription(field), field.Name))

        Next

    End Sub

  

End Class

The usage is quite simple, as the example in the comment shows. Here's the markup for the control:

       1: <app:EnumList Runat="server" ID="ddlRegion" DataSource="MyApp.RegionCode" />
  

And in the code-behind, it's wired up as follows:

       1: ddlRegion.DataBind()

       2: ddlRegion.SelectedValue = RegionCode.West

Here's the result. I chose to have the value of the dropdown be the enum field name rather than its value, because that felt cleaner.

       1: <select name="dnn$ctr396$ManageJobs$ddlRegion" id="dnn_ctr396_ManageJobs_ddlRegion">

       2:     <option value="NotSelected">-- Select --</option>

       3:     <option value="Midwest">US - Midwest</option>

       4:     <option value="Northeast">US - Northeast</option>

       5:     <option value="Southeast">US - Southeast</option>

       6:     <option value="Southwest">US - Southwest</option>

       7:     <option selected="selected" value="West">US - West</option>

       8:     <option value="Canada">Canada</option>

       9: </select>

I suspect that there are going to be some goofy bugs in here if this was hit with some complex scenarios. But fortunately for me, this project won't have any complex scenarios.

Technorati Tags: ASP.NET,Visual Basic,Enum,DropDownList

Your Comments.

# re: Enum List DropDown Control
This looks great but...
One thing that I am unsure about.

How do you go about registeriing this EnumList control with the webpage?

Left by rpcutts at 5/6/2008 7:12 AM
# re: Enum List DropDown Control
Here's a quick reference for how to register a custom control and use it.

http://msdn.microsoft.com/en-us/library/1e9b4c9f(VS.71).aspx

Sorry, I took that aspect for granted!

Left by Jeff Handley at 5/14/2008 1:07 AM
# re: Enum List DropDown Control
Thank's, I imagine you're quite right to take it for granted.
You can't cover everything in every post after all.

Left by rpcutts at 5/14/2008 4:43 AM
# re: Enum List DropDown Control
Hi there Jeff!

for the life of me I cannot get this example of yours to work!

Would it be possible to email you re this as it is just what I am after!

Thanks in anticipation!

Left by Tuppers! at 5/18/2009 6:02 AM
# re: Enum List DropDown Control
Hey Jeff nice tip and example.

I did this in C# using extension methods like you suggested and its working great.

I was just trying to think of a way to make it a little more generic. I have a similar need to use this with ListBox, RadioButtonList and CheckBoxList controls also. Is there a way to do this without having to repeat the same code over?

Thanks

Left by Janaka at 11/24/2009 4:45 PM
# re: Enum List DropDown Control
Why go to tall that trouble when you could just bind your combobox to an enum in a single line? What I am missing?

Left by dividend at 12/10/2009 9:01 AM
# re: Enum List DropDown Control
@dividend - The point was to get descriptions to show up in the dropdown instead of just the enum member name.

Left by Jeff Handley at 12/10/2009 9:03 AM